Cetak dua lembar excel dalam satu halaman pdf

Buku kerja bisa berisi semua jenis data. Jika Anda memiliki buku kerja yang menyertakan sejumlah lembar kerja, masing-masing hanya berisi sejumlah kecil data, Anda mungkin bertanya-tanya apakah ada cara untuk mencetak beberapa lembar kerja pada satu lembar kertas.

Ada beberapa cara yang dapat Anda lakukan untuk mendekati solusi untuk masalah ini. Yang pertama cukup cetak beberapa halaman per lembar, menggunakan kemampuan driver printer Anda. Misalnya, saya memiliki HP LaserJet lama, dan driver printer memungkinkan saya untuk menentukan jumlah halaman yang akan dicetak per lembar kertas. Jika saya ingin mencetak tiga atau empat lembar kerja satu halaman dalam satu lembar kertas, yang perlu saya lakukan hanyalah mengikuti langkah-langkah ini

1. Pilih Cetak dari menu File. Excel menampilkan kotak dialog Cetak
2. Di area Cetak Apa dari kotak dialog, pilih opsi Keseluruhan Buku Kerja
3. Klik tombol Properti. Excel menampilkan kotak dialog Properties untuk printer, dengan tab Layout dipilih
4. Atur kontrol Pages Per Sheet ke 4
5. Klik OK untuk menutup kotak dialog Properti
6. Klik OK untuk benar-benar mencetak lembar kerja

Printer Anda mungkin menawarkan kemampuan serupa dengan apa yang diuraikan di sini, tetapi Anda mungkin perlu menjelajahi kotak dialog Properti printer untuk menemukan kemampuan itu. Tentu saja, pencetakan dengan cara ini dapat menghasilkan teks yang sangat kecil pada hasil cetak, karena driver printer hanya mengurangi setiap halaman untuk memenuhi area yang proporsional dari halaman yang dicetak. Jika Anda ingin mengurangi sebagian ruang putih, dan dengan demikian memperbesar ukuran teks yang dicetak, Anda perlu mencari solusi lain

Banyak orang, untuk mengonsolidasikan apa yang dicetak, sebenarnya membuat "lembar kerja pencetakan" yang berisi referensi ke area yang akan dicetak pada lembar kerja lain di buku kerja. Referensi ini dapat dilakukan melalui rumus yang mengacu pada data di setiap lembar kerja, atau dengan menggunakan alat kamera di Excel. (Alat kamera telah dijelaskan dalam edisi lain dari ExcelTips. )

Untuk solusi otomatis menggabungkan beberapa lembar kerja menjadi satu lembar kerja, Anda bisa menggunakan makro. Makro berikut akan membuat lembar kerja baru di akhir buku kerja Anda dan menyalin konten dari semua lembar kerja lain ke dalamnya

Sub PrintOnePage()
    Dim wshTemp As Worksheet, wsh As Worksheet
    Dim rngArr() As Range, c As Range
    Dim i As Integer
    Dim j As Integer

    ReDim rngArr(1 To 1)
    For Each wsh In ActiveWorkbook.Worksheets
        i = i + 1
        If i > 1 Then   ' resize array
            ReDim Preserve rngArr(1 To i)
        End If

        On Error Resume Next
        Set c = wsh.Cells.SpecialCells(xlCellTypeLastCell)
        If Err = 0 Then
            On Error GoTo 0

            'Prevent empty rows
            Do While Application.CountA(c.EntireRow) = 0 _
              And c.EntireRow.Row > 1
                Set c = c.Offset(-1, 0)
            Loop

            Set rngArr(i) = wsh.Range(wsh.Range("A1"), c)
        End If
    Next wsh

    'Add temp.Worksheet
    Set wshTemp = Sheets.Add(after:=Worksheets(Worksheets.Count))

    On Error Resume Next
    With wshTemp
        For i = 1 To UBound(rngArr)
            If i = 1 Then
                Set c = .Range("A1")
            Else
                Set c = _
                  ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell)
                Set c = c.Offset(2, 0).End(xlToLeft)  'Skip one row
            End If

            'Copy-paste range (prevent empty range)
            If Application.CountA(rngArr(i)) > 0 Then
                rngArr(i).Copy c
            End If
        Next i
    End With
    On Error GoTo 0

    Application.CutCopyMode = False ' prevent marquies

    With ActiveSheet.PageSetup     'Fit to 1 page
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
    End With

    'Preview New Sheet
    ActiveWindow.SelectedSheets.PrintPreview

    'Print Desired Number of Copies
    i = InputBox("Print how many copies?", "ExcelTips", 1)
    If IsNumeric(i) Then
        If i > 0 Then
            ActiveSheet.PrintOut Copies:=i
        End If
    End If

    'Delete temp.Worksheet?
    If MsgBox("Delete the temporary worksheet?", _
      vbYesNo, "ExcelTips") = vbYes Then
        Application.DisplayAlerts = False
        wshTemp.Delete
        Application.DisplayAlerts = True
    End If
End Sub

Setelah lembar kerja gabungan disatukan, makro menampilkan lembar kerja menggunakan Pratinjau Cetak. Saat Anda menutup Pratinjau Cetak, ia menanyakan berapa banyak salinan lembar kerja yang ingin Anda cetak. Jika Anda memasukkan angka yang lebih besar dari nol, maka banyak salinan yang dicetak. Terakhir, makro menawarkan untuk menghapus lembar kerja gabungan untuk Anda sebelum selesai

Masalah kami dimulai sekitar 3 minggu yang lalu. Tidak ada pembaruan di Adobe Acrobat DC. Menggunakan saran Anda, satu-satunya cara saya akhirnya bisa mencetak buku kerja ke SATU pdf, adalah dengan memilih setiap tab, lalu SIMPAN spreadsheet excel ke PDF (daripada PRINT ke pdf). Mengganggu - tetapi berhasil lagi.   

Terima kasih semuanya, atas petunjuk Anda. Jauh lebih mudah daripada mengeluarkan banyak pdf untuk satu buku kerja, dan kemudian harus menggabungkannya. 🙂

Bisakah saya mencetak beberapa lembar Excel ke satu PDF?

Bagaimana cara mencetak dua lembar kerja Excel pada satu halaman?

Bagaimana cara mencetak banyak tab pada satu PDF?

Bagaimana cara menggabungkan tab Excel menjadi satu PDF?